rename wwan-related modules/services

we only currently support huawei e3372/cdc ncm so let's make that
explicit in the naming

modules/wwan/default.nix

@@ -0,0 +1,31 @@
+{ config, pkgs, lib, ... }:
+let
+  inherit (pkgs) liminix;
+  inherit (lib) mkOption types;
+in {
+  imports = [
+    ../service-trigger
+  ];
+
+  options = {
+    system.service.wwan.huawei-e3372 = mkOption {
+      type = liminix.lib.types.serviceDefn;
+    };
+  };
+  config = {
+    kernel.config = {
+      USB_NET_HUAWEI_CDC_NCM = "y";
+      USB_USBNET = "y";
+      USB_SERIAL = "y";
+      USB_SERIAL_OPTION = "y";
+    };
+
+    # https://www.0xf8.org/2017/01/flashing-a-huawei-e3372h-4g-lte-stick-from-hilink-to-stick-mode/
+    system.service.wwan.huawei-e3372 = config.system.callService ./huawei-e3372.nix {
+      apn = mkOption { type = types.str; };
+      username = mkOption { type = types.str; };
+      password = mkOption { type = types.str; };
+      authType = mkOption { type = types.enum [ "pap" "chap" ]; };
+    };
+  };
+}

modules/wwan/huawei-e3372.nix

@@ -0,0 +1,70 @@
+{
+  liminix
+, usb-modeswitch
+, ppp
+, lib
+, svc
+, uevent-watch
+}:
+{ apn, username, password, authType }:
+let
+  inherit (liminix.services) oneshot;
+  authTypeNum = if authType == "pap" then "1" else "2";
+  chat = lib.escapeShellArgs [
+    # Your usb modem thing might present as a tty that you run PPP
+    # over, or as a network device ("ndis" or "ncm"). The latter
+    # kind is to be preferred, at least in principle, because it's
+    # faster.  This initialization sequence works for the Huawei
+    # E3372, and took much swearing: the error messages are *awful*
+    "" "AT"
+    "OK" "ATZ"
+    # create PDP context
+    "OK" "AT+CGDCONT=1,\"IP\",\"${apn}\""
+    # activate PDP context
+    "OK"  "AT+CGACT=1,1"
+    # setup username and password per requirements of sim provider.
+    # (caret is special to chat, so needs escaping in AT commands)
+    "OK"  "AT\\^AUTHDATA=1,${authTypeNum},\"\",\"${password}\",\"${username}\""
+    # start the thing (I am choosing to read this as "NDIS DialUP")
+    "OK" "AT\\^NDISDUP=1,1"
+    "OK"
+  ];
+  modeswitch = oneshot rec {
+    name = "modem-modeswitch";
+    controller = (svc.uevent-rule.build {
+      serviceName = name;
+      terms = { devtype = "usb_device"; product = "12d1/14fe/102"; };
+    });
+    up = ''
+      ${usb-modeswitch}/bin/usb_modeswitch -v 12d1 -p 14fe --huawei-new-mode
+    '';
+  };
+  atz = oneshot rec {
+    name = "modem-atz";
+    # atz does not depend on modeswitch because modeswitch service
+    # is only running when the stick is in the wrong mode
+    dependencies = [ modeswitch.controller ];
+    buildInputs = [ modeswitch ];
+    controller = (svc.uevent-rule.build {
+      serviceName = name;
+      terms = {
+        subsystem = "tty";
+        attrs = {
+          idVendor = "12d1";
+          idProduct = "1506";
+        };
+      };
+      symlink = "/dev/modem";
+    });
+    up = ''
+      ls -l /dev/modem
+      test -L /dev/modem || exit 1
+      ${ppp}/bin/chat -s -v ${chat}  0<>/dev/modem 1>&0
+    '';
+    down = "${ppp}/bin/chat -v '' ATZ OK  0<>/dev/modem 1>&0";
+  };
+
+in svc.network.link.build {
+  ifname = "wwan0";
+  dependencies = [ atz ];
+}