extract "mount filesystem" to module

modules/mount/default.nix

@@ -0,0 +1,49 @@
+
+{ lib, pkgs, config, ...}:
+let
+  inherit (lib) mkOption types;
+  inherit (pkgs) liminix;
+  mkBoolOption = description : mkOption {
+    type = types.bool;
+    inherit description;
+    default = true;
+  };
+
+in {
+  options = {
+    system.service.mount = mkOption {
+      type = liminix.lib.types.serviceDefn;
+    };
+  };
+  config.system.service = {
+    mount = liminix.callService ./service.nix {
+      device = mkOption {
+        type = types.str;
+        example = "/dev/sda1";
+      };
+      mountpoint = mkOption {
+        type = types.str;
+        example = "/mnt/media";
+      };
+      options = mkOption {
+        type = types.listOf types.str;
+        default = [];
+        example = ["noatime" "ro" "sync"];
+      };
+      fstype = mkOption {
+        type = types.str;
+        default = "auto";
+        example = "vfat";
+      };
+    };
+  };
+  config.programs.busybox  = {
+    applets = ["blkid" "findfs"];
+    options = {
+      FEATURE_BLKID_TYPE = "y";
+      FEATURE_MOUNT_FLAGS = "y";
+      FEATURE_MOUNT_LABEL = "y";
+      FEATURE_VOLUMEID_EXT = "y";
+    };
+  };
+}

modules/mount/service.nix

@@ -0,0 +1,18 @@
+{
+  liminix
+, lib
+}:
+{ device, mountpoint, options, fstype }:
+let
+  inherit (liminix.services) oneshot;
+in oneshot {
+  name = "mount.${lib.escapeURL mountpoint}";
+  up = ''
+    while ! findfs ${device}; do
+      echo waiting for device ${device}
+      sleep 1
+    done
+    mount -t ${fstype} -o ${lib.concatStringsSep "," options} ${device} ${mountpoint}
+  '';
+  down = "umount ${mountpoint}";
+}