{
  self,
  hostPkgs,
  config,
  lib,
  ...
}:
{
  name = "service-phonebox-global";
  result.update-vars =
    let
      relativeDir = lib.removePrefix "${self}/" (toString config.clan.directory);
    in
    hostPkgs.writeShellScriptBin "update-vars" ''
      set -x
      export PRJ_ROOT=$(git rev-parse --show-toplevel)
      ${
        self.inputs.clan-core.packages.${hostPkgs.system}.clan-cli
      }/bin/clan-generate-test-vars $PRJ_ROOT/${relativeDir} ${config.name}
    '';

  clan = {
    test.useContainers = false;
    directory = ./.;
    inventory = {
      machines.server = { };
      machines.nodeA = { };

      instances = {
        yggdrasil = {
          module.name = "yggdrasil";
          roles.default.machines.server = { };
          roles.default.machines.nodeA = { };
        };
        phonebox-global-test = {
          module.name = "@clan/phonebox-global";
          module.input = "self";
          roles.default.machines.server.settings.ata-ethernet-iface = "enp2s0";
          roles.default.machines.nodeA.settings.ata-ethernet-iface = "enp2s0";
        };
      };
    };
  };

  nodes = {
    server = { };
    nodeA = { };
  };

  testScript =
    { nodes, ... }:
    let
      number = node: nodes.${node}.clan.core.vars.generators.phonebox-global.files.number.value;
      address = node: nodes.${node}.clan.core.vars.generators.yggdrasil.files.address.value;
    in
    ''
      start_all()

      for node in [server, nodeA]:
          node.wait_for_unit("asterisk.service")
          node.wait_for_unit("phonebox-directory.service")

      # Directory converges: each node learns the other's number and address.
      server.wait_until_succeeds("test -f /run/phonebox/numbers/${number "nodeA"}", timeout=300)
      nodeA.wait_until_succeeds("test -f /run/phonebox/numbers/${number "server"}", timeout=300)
      assert server.succeed("cat /run/phonebox/numbers/${number "nodeA"}") == "${address "nodeA"}"
      assert nodeA.succeed("cat /run/phonebox/numbers/${number "server"}") == "${address "server"}"
      assert "${number "nodeA"}" in server.succeed("cat /run/phonebox/contacts.txt")

      # A call from server to nodeA's number is routed over yggdrasil and
      # accepted by nodeA's asterisk (no phone is registered, so it fails
      # after being identified, which is enough to prove the path).
      nodeA.succeed("asterisk -rx 'pjsip set logger on'")
      server.succeed("asterisk -rx 'channel originate Local/${number "nodeA"}@from-internal application Wait 3'")
      nodeA.wait_until_succeeds("grep -q 'INVITE sip:${number "nodeA"}@' /var/log/asterisk/full", timeout=60)
    '';
}