{ inputs }:
{
  config,
  pkgs,
  modulesPath,
  lib,
  ...
}:
let
  secrets = {
    firewallRules = { };
  }
  // (import ./secrets.nix);
  wirelessConfig = {
    country_code = "TH";
    inherit (secrets) wpa_passphrase;
    wmm_enabled = 1;
  };
  svc = config.system.service;
in
{
  imports = [
    "${inputs.liminix}/modules/wlan.nix"
    "${inputs.liminix}/modules/network"
    "${inputs.liminix}/modules/vlan"
    "${inputs.liminix}/modules/ssh"
    "${inputs.liminix}/modules/bridge"
    "${inputs.liminix}/modules/health-check"
    "${modulesPath}/profiles/wap.nix"
  ];

  hostname = "whitehouse-2";
  boot = {
    tftp = {
      freeSpaceBytes = 3 * 1024 * 1024;
      serverip = "${secrets.lan.prefix}.149";
      ipaddr = "${secrets.lan.prefix}.252";
    };
  };

  services.sshd = svc.ssh.build {
    authorizedKeys.root = secrets.root.openssh.authorizedKeys.keys;
  };

  users.root = secrets.root;

  services.resolvconf = lib.mkForce (
    pkgs.liminix.services.oneshot rec {
      name = "resolvconf";
      up = ''
        ( in_outputs ${name}
         echo "nameserver 208.67.222.222" >> resolv.conf
         echo "nameserver 208.67.220.220" >> resolv.conf
         echo "nameserver 1.1.1.1" >> resolv.conf
         echo "nameserver 1.0.0.1" >> resolv.conf
         echo "nameserver 8.8.8.8" >> resolv.conf
         chmod 0444 resolv.conf
        )
      '';
    }
  );

  profiles.wap = {
    interfaces = with config.hardware.networkInterfaces; [
      lan
      wlan
      wlan5
    ];

    wireless.networks = {
      "${secrets.ssid}" = {
        interface = config.hardware.networkInterfaces.wlan;
        hw_mode = "g";
        channel = "2";
        ieee80211n = 1;
      }
      // wirelessConfig;
      "${secrets.ssid}-5" = rec {
        interface = config.hardware.networkInterfaces.wlan5;
        hw_mode = "a";
        channel = 36;
        ht_capab = "[HT40+]";
        vht_oper_chwidth = 1;
        vht_oper_centr_freq_seg0_idx = channel + 6;
        ieee80211n = 1;
        ieee80211ac = 1;
      }
      // wirelessConfig;
    };
  };

  defaultProfile.packages = with pkgs; [
    busybox
    iw
    nftables
  ];

}